[Erlang] OTP

#Erlang

OTP는 Open Telecom Platform의 축약으로, Erlang의 분산시스템용 라이브러리 모음, 혹은 그러한 아키텍처를 말한다.
Erlang의 존재 목적이기도 하다.

Telecom이 들어가있긴 한데, 통신에만 쓸수 있는건 아니고, 막 엄청난 프레임워크를 말하는 것도 아니다.
그냥 채널 등을 포함한 erlang의 하위 기능요소들과, 그걸 이용한 구현 패턴을 말하는 것이다.

현재의 비동기-분산시스템의 이론적 모태이기도 하다.
흔히 Go, Rust에서 사용되는 채널의 개념이 여기에서 나왔다.

supervision tree

erlang OTP는 supervision tree라는 형태로 프로세스 간의 연결, 통신을 관리한다.
여기서 동그라미가 Worker, 네모가 Supervisor다. OTP에서는 이 둘을 엄격하게 구분해서 역할을 구분한다.

Worker는 순수한 의미의 작업자 프로세스다. 실제로 의미가 있는 작업들을 처리한다.
하지만 worker는 언제든 Supervisor에 의해 사라지거나, 생기거나, 변동될 수 있다.

Supervisor는 worker들을 관리만 하는 관리 전용 프로세스다.

erlang OTP는 이러한 구조를 통해 내결함성(fault-tolerant)을 보장한다.

근데 erlang이 이러한 구조 템플릿을 친절하게 제공하는건 아니라서, 직접 구현해야 하는게 많다. 그래서 여기에서는 간단한 사용 형태만 대충 보이고 제대로 된 워커 트리 구조는 나중에 다뤄보겠다.

간단한 프로그램 만들어보기

예시로 간단한 중앙 서버가 있고, 중앙 서버에 rpc를 통해 로직을 제공하는 하위 서버를 구성하는 코드를 보여보겠다.

우선 서버 코드다.

-module(server). 
-export([start/2, rpc/2]). 

% 특정 이름을 가지는 서버 루프를 시작한다.
start(Name, Mod) -> 
   register(Name, spawn(fun() -> loop(Name, Mod, Mod:init()) end)). 

% 특정 이름을 가진 프로세스에게 Request를 보내고, Response를 받는다.
rpc(Name, Request) -> 
   Name ! {self(), Request}, 
   receive 
      {Name, Response} -> Response 
   end. 

% 무한루프를 돌며 계속해서 Request를 받고, Mod:handle/2를 호출하여 Response를 반환한다.
loop(Name, Mod, State) ->
   receive 
      {From, Request} ->
         {Response, State1} = Mod:handle(Request, State), 
         From ! {Name, Response}, 
         loop(Name, Mod, State1) 
   end.

start 함수는 하위 서버의 이름과, 모듈명을 전달받고 모듈을 서버에 등록한다.
그리고 rpc 함수를 통해서 등록된 하위서버들에 요청을 보내고 응답을 받아올 수 있다.

그 다음에는 하위서버로 사용할 name_server 코드를 작성해보겠다.
그냥 딕셔너리 하나 두고, 키:값 쌍을 추가하고 조회할 수만 있는 단순한 기능을 가진다.

-module(name_server). 
-export([init/0, add/2, whereis/1, handle/2]). 
-import(server, [rpc/2]). 

% 중앙 서버에 rpc 요청 (중앙 서버에서 다시 handler로 echo)
add(Name, Place) -> rpc(name_server, {add, Name, Place}). 
whereis(Name) -> rpc(name_server, {whereis, Name}). 

init() -> dict:new().

% rpc 호출시 응답할 핸들러들
handle({add, Name, Place}, Dict) -> {ok, dict:store(Name, Place, Dict)}; 
handle({whereis, Name}, Dict) -> {dict:find(Name, Dict), Dict}.